ActionScript 3.0, l'essentiel sous la main Adobe Flash Accueil
Fiches
Boutique
Contact
Uploader un fichier - En local dans Flash (pour les images uniquement)
Nous allons voir ici comment uploader une image dans son application à l'aide d'un bouton "Parcourir". La différence avec un import que l'on peu faire avec un fichier externe, c'est qu'ici le fichier charger peu se trouver n'importe où et pas à une URL fixe. De plus, cette methode ne nécessite aucun fichier PHP et peut donc fonctionner en local.

Créer :
//Imports Flash
import flash.events.Event;
import flash.events.MouseEvent;
import flash.display.Loader;
import flash.net.FileFilter;
import flash.utils.ByteArray;

var fichier:FileReference; //Stockage du fichier externe
var dataImage:Loader; //Stockage des données bitmap à afficher

//Types de fichiers autorisés
var formats:FileFilter = new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg; *.jpeg; *.gif; *.png");

//Recherche du fichier
function parcourir(e:MouseEvent):void
{
fichier = new FileReference();
fichier.addEventListener(Event.SELECT, fichierSelect);
fichier.browse([formats]);
}
btn_parcourir.addEventListener(MouseEvent.CLICK, parcourir);

//Téléchargement du fichier sélectionné
function fichierSelect(e:Event):void
{
fichier.addEventListener(Event.COMPLETE, endLoadData);
fichier.load();
}

//Lorsque le chargement est terminé
function endLoadData(e:Event):void
{
//Suppression des écouteurs inutiles
fichier.removeEventListener(Event.SELECT, fichierSelect);
fichier.removeEventListener(Event.COMPLETE, endLoadData);

//Stockage des données reçu
var dataFile:ByteArray = fichier.data;

//Chargement des données bitmap dans un loader pour affichage
dataImage = new Loader();
dataImage.contentLoaderInfo.addEventListener(Event.COMPLETE, loadingImage);
dataImage.loadBytes(dataFile);
}

//Affiche des données bitmap chargées
function loadingImage(e:Event):void
{
//Suppression de l'écouteur inutile
dataImage.contentLoaderInfo.removeEventListener(Event.COMPLETE, loadingImage);

//Affiche l'image
zoneLoad.addChild(dataImage);
}

Aperçus & Sources : (Flash CS5)
Commentaire(s)
Aucun.